summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: b7cf0ce7837b58c31cc04b2716654d7f4329a60c (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>

pkgbase=tsmuxer-ng-bin
pkgname=('tsmuxer-ng-cli-bin'
         'tsmuxer-ng-gui-bin'
         )
pkgver=2.6.11
pkgrel=1
pkgdesc="Transport Stream muxer. New Generation (3D capable)"
arch=('x86_64')
url='http://forum.doom9.org/showthread.php?t=168539'
license=('custom')
makedepends=('upx')
source=("tsmuxer-${pkgver}.tar.gz::https://docs.google.com/uc?authuser=0&id=0B0VmPcEZTp8NekJxLUVJRWMwejQ&export=download"
        'tsmuxergui.desktop'
        'tsmuxergui.png'
        )
sha256sums=('815a383aebc67e59b6e541b927ce14480efed9d103fe99e74ced9ea381f61764'
            'aed84b10da52849c14acb6bfb8b806c9675e4c8bcf781590712bbedc332b443f'
            '5d1a6b9e88a82d40a0159d95bb596a7dc4502d7164364098e4cc3ddef72632c0'
            )
options=('!strip')

package_tsmuxer-ng-cli-bin() {
  pkgdesc="Transport Stream muxer. New Generation (3D capable). CLI"
  depends=('lib32-gcc-libs'
           'lib32-freetype2'
           )
  provides=('tsmuxer-cli'
            'tsmuxer-ng-cli'
            )
  conflicts=('tsmuxer'
             'tsmuxer-cli'
             'tsmuxer-cli-ng'
             'tsmuxer-ng-cli'
             )

  install -Dm755 tsMuxeR "${pkgdir}/usr/bin/tsmuxer"
  (cd ${pkgdir}/usr/bin; upx -d -q tsmuxer &>/dev/null)
}

package_tsmuxer-ng-gui-bin() {
  pkgdesc="Transport Stream muxer. New Generation (3D capable). GUI"
  depends=('lib32-gcc-libs'
           'lib32-qt4'
          )
  provides=('tsmuxer-gui'
            'tsmuxer-ng-gui'
            )
  conflicts=('tsmuxer'
             'tsmuxer-gui'
             'tsmuxer-gui-ng'
             'tsmuxer-ng-gui'
             )

  install -Dm755 tsMuxerGUI "${pkgdir}/usr/bin/tsmuxergui"
  (cd ${pkgdir}/usr/bin; upx -d -q tsmuxergui &>/dev/null)

  install -Dm644 tsmuxergui.desktop "${pkgdir}/usr/share/applications/tsmuxergui.desktop"
  install -Dm644 tsmuxergui.png "${pkgdir}/usr/share/pixmaps/tsmuxergui.png"
}