PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>
# Contributor: Jerome Leclanche <jerome.leclanche+arch@gmail.com>
# Contributor: Andrea Scarpino <andrea@archlinux.org>

pkgname=ttf-oxygen-git
pkgver=5.3.90.r168.4a2d1f7
pkgrel=1
pkgdesc="A desktop/gui font family for integrated use with the KDE desktop. (GIT version)"
arch=('any')
license=('custom:OFL')
url='https://projects.kde.org/projects/playground/artwork/oxygen-fonts'
makedepends=('git' 'cmake' 'extra-cmake-modules' 'fontforge')
provides=('ttf-oxygen')
conflicts=('ttf-oxygen')
source=('git://anongit.kde.org/oxygen-fonts.git')
sha1sums=('SKIP')
install=ttf-oxygen-git.install

pkgver() {
  cd oxygen-fonts
  _ver="$(cat CMakeLists.txt | grep -m1 PROJECT_VERSION | cut -d '"' -f2)"
  echo "${_ver}.r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../oxygen-fonts \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DLIB_INSTALL_DIR=lib \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON
  make
}

package() {
  make -C build DESTDIR="${pkgdir}" install
}