blob: 959078ed47eb9a0138e81c06282259f67d49606b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Maintainer: Mario Finelli <mario at finel dot li>
# Contributor: Arthur Titeica <arthur dot titeica at gmail dot com>
pkgname=ttfautohint-git
pkgver=1.8.4.r13.g87a4ebf
pkgrel=1
pkgdesc='Provides automated hinting process for web fonts'
arch=(x86_64 i686)
url="http://www.freetype.org/${pkgname%-git}"
license=('GPL-2.0-or-later OR FTL')
depends=(freetype2
harfbuzz
qt5-base)
makedepends=(git
imagemagick
inkscape
noto-fonts
pandoc
texlive-core
xorg-xwininfo)
conflicts=("${pkgname/%-git}")
provides=("${pkgname/%-git}=$pkgver")
source=("$pkgname::git://repo.or.cz/${pkgname/-/.}"
"gnulib-git::git+https://git.savannah.gnu.org/git/gnulib.git")
sha256sums=('SKIP'
'SKIP')
prepare(){
cd "$pkgname"
git submodule init
git config submodule.gnulib.url "$srcdir/gnulib-git"
git -c protocol.file.allow=always submodule update
./bootstrap --force
}
pkgver() {
cd "$pkgname"
git describe --tags --abbrev=7 --match="v*" HEAD |
sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "$pkgname"
export QMAKE='/usr/bin/qmake'
export MOC='/usr/bin/moc'
export UIC='/usr/bin/uic'
export RCC='/usr/bin/rcc'
export TTFONTS='/usr/share/fonts/noto'
./configure \
--without-doc \
--prefix=/usr \
--with-qt=/usr/lib/qt \
--with-freetype-config="pkg-config freetype2"
make
}
check() {
cd "$pkgname"
make -k check
}
package() {
cd "$pkgname"
make DESTDIR="$pkgdir" install
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" COPYING FTL.TXT
}
|