blob: 94ffb96e628d85e1c899ec785f8194f4ef9b3a1d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: flossbud <flossbud27@gmail.com>
pkgname=ttmt-beta
epoch=1
_upstream=0.8.0-alpha.1
pkgver=0.8.0alpha.1
pkgrel=1
pkgdesc="ToonTown MultiTool BETA, pre-release smoke-test channel. Expect bugs. For stable use, install toontown-multitool instead."
arch=('any')
url="https://github.com/flossbud/ToonTown-MultiTool"
license=('MIT')
depends=(
'python'
'pyside6'
'qt6-svg'
'python-pynput'
'python-requests'
'python-keyring'
'python-certifi'
'python-cryptography'
'python-xlib'
'python-secretstorage'
'python-jeepney'
'python-psutil'
'python-yaml'
'xdotool'
)
makedepends=('git')
source=("git+https://github.com/flossbud/ToonTown-MultiTool.git#tag=v${_upstream}")
sha256sums=('SKIP')
package() {
cd "ToonTown-MultiTool"
# Install Python source
install -dm755 "${pkgdir}/usr/share/${pkgname}"
cp -r main.py tabs/ utils/ services/ assets/ "${pkgdir}/usr/share/${pkgname}/"
# Launcher sets TTMT_BETA=1 so build_flavor switches.
install -dm755 "${pkgdir}/usr/bin"
cat > "${pkgdir}/usr/bin/${pkgname}" << 'EOF'
#!/bin/bash
export TTMT_BETA=1
exec python /usr/share/ttmt-beta/main.py "$@"
EOF
chmod 755 "${pkgdir}/usr/bin/${pkgname}"
# Separate desktop entry — coexists with stable.
install -Dm644 /dev/stdin \
"${pkgdir}/usr/share/applications/io.github.flossbud.ToonTownMultiTool-beta.desktop" << 'EOF'
[Desktop Entry]
Name=ToonTown MultiTool (Beta)
Comment=Pre-release smoke-test build, expect bugs
Exec=ttmt-beta
Icon=ttmt-beta
StartupWMClass=io.github.flossbud.ToonTownMultiTool-beta
Terminal=false
Type=Application
Categories=Game;
EOF
# Beta-badged icon at a separate icon name so the .desktop's Icon=ttmt-beta resolves.
install -Dm644 assets/ToonTownMultiTool-beta.png \
"${pkgdir}/usr/share/icons/hicolor/1024x1024/apps/ttmt-beta.png"
}
|