PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Contributor: Ninez <triplesquarednine AT gmail DOT com>
# Contributor: N30N <archlinux@alunamation.com>
# Maintainer: SanskritFritz (gmail)

pkgname="tupi-git"
pkgver=156.11cadda
pkgrel=2
pkgdesc="A 2D animation tool for 8-100 years old kids."
url="http://www.maefloresta.com/"
license=("GPL3")
arch=("i686" "x86_64")
depends=("qt5-tools" "qt5-multimedia" "qt5-svg" "quazip-qt5" "libtheora" "ffmpeg" "aspell" "shared-mime-info")
makedepends=("git" "ruby" "zlib" "libgl")
source=("git://anongit.kde.org/tupi" "quazip5.patch")
md5sums=('SKIP'
         'c8e05ddef493102349e3f15b07e0c6e2')
install="tupi.install"

prepare() {
	cd tupi
	patch -p1 -i ../quazip5.patch
}

pkgver() {
	cd tupi
	echo $(git rev-list --count HEAD).$(git rev-parse --short HEAD)
}

build() {
	cd tupi
	./configure \
		--prefix="/usr" \
		--libdir="/usr/lib" \
		--with-quazip="/usr" \
		# --sharedir="/usr/share/tupi"
		# --with-debug \
	make
}

package() {
	cd tupi
	make DESTDIR="$pkgdir" install

	sed "s|$pkgdir||" -i "$pkgdir/usr/bin/tupi"
}