blob: 126e4c1079ca6334152999f7cefe8053a14183ae (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=turtle
_app_id="de.philippun1.$pkgname"
pkgver=0.6.1
pkgrel=1
pkgdesc="Manage your git repositories with easy-to-use dialogs in Nautilus."
arch=('any')
url="https://gitlab.gnome.org/philippun1/turtle"
license=('GPL3')
depends=('libadwaita' 'meld' 'python-gobject' 'python-pygit2')
makedepends=('python-build' 'python-installer' 'python-setuptools' 'python-wheel')
#checkdepends=('appstream-glib' 'python-pytest')
checkdepends=('appstream-glib')
optdepends=('python-nautilus: Nautilus plugin'
'thunarx-python: Thunar plugin'
'nemo-python: Nemo plugin'
'python-caja: Caja plugin')
conflicts=('turtlegit')
source=("$url/-/archive/$pkgver/$pkgname-$pkgver.tar.gz")
sha256sums=('2172f657161edc9de4d66f44beeac37bdf8f266267858f170746168784db84fe')
build() {
cd "$pkgname-$pkgver"
python -m build --wheel --no-isolation
}
check() {
cd "$pkgname-$pkgver"
# PYTHONPATH=./ pytest
appstream-util validate-relax --nonet "data/${_app_id}.metainfo.xml"
desktop-file-validate "data/${_app_id}.desktop"
}
package() {
cd "$pkgname-$pkgver"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 "data/icons/hicolor/scalable/apps/${_app_id}.svg" -t \
"$pkgdir/usr/share/icons/hicolor/scalable/apps/"
install -Dm644 "data/icons/hicolor/symbolic/apps/${_app_id}-symbolic.svg" -t \
"$pkgdir/usr/share/icons/hicolor/symbolic/apps/"
install -Dm644 "data/${_app_id}.desktop" -t "$pkgdir/usr/share/applications/"
install -Dm644 "data/${_app_id}.gschema.xml" -t "$pkgdir/usr/share/glib-2.0/schemas/"
install -Dm644 "data/${_app_id}.metainfo.xml" -t "$pkgdir/usr/share/metainfo/"
install -Dm644 "plugins/${pkgname}"{_nautilus.py,_nautilus_compare.py} -t \
"$pkgdir/usr/share/nautilus-python/extensions/"
install -Dm644 "plugins/${pkgname}_thunar.py" -t \
"$pkgdir/usr/share/thunarx-python/extensions/"
install -Dm644 "plugins/${pkgname}_nemo.py" -t \
"$pkgdir/usr/share/nemo-python/extensions/"
install -Dm644 "plugins/${pkgname}_caja.py" -t \
"$pkgdir/usr/share/caja-python/extensions/"
}
|