blob: ac4e7f4de94e5f74b2012189ca6b22450d34237b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=turtle-git
_app_id="de.philippun1.${pkgname%-git}"
pkgver=0.8.r0.g9f8a7a3
pkgrel=1
pkgdesc="Manage your git repositories with easy-to-use dialogs in Nautilus."
arch=('any')
url="https://gitlab.gnome.org/philippun1/turtle"
license=('GPL-3.0-or-later')
depends=(
'libadwaita'
'meld'
'python-dbus'
'python-gobject'
'python-pygit2'
)
makedepends=(
'git'
'python-build'
'python-installer'
'python-setuptools'
'python-wheel'
)
checkdepends=('appstream')
#checkdepends+=('python-pytest')
optdepends=(
'python-nautilus: Nautilus plugin'
'thunarx-python: Thunar plugin'
'nemo-python: Nemo plugin'
'python-caja: Caja plugin'
)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}" 'turtlegit')
source=('git+https://gitlab.gnome.org/philippun1/turtle.git')
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/${pkgname%-git}"
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "$srcdir/${pkgname%-git}"
python -m build --wheel --no-isolation
}
check() {
cd "$srcdir/${pkgname%-git}"
# PYTHONPATH=./ pytest
appstreamcli validate --no-net "data/${_app_id}.metainfo.xml"
desktop-file-validate "data/${_app_id}.desktop"
}
package() {
cd "$srcdir/${pkgname%-git}"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm755 "${pkgname%-git}_cli" -t "$pkgdir/usr/bin/"
install -Dm644 "data/icons/hicolor/scalable/apps/${_app_id}.svg" -t \
"$pkgdir/usr/share/icons/hicolor/scalable/apps/"
install -Dm644 "data/icons/hicolor/symbolic/apps/${_app_id}-symbolic.svg" -t \
"$pkgdir/usr/share/icons/hicolor/symbolic/apps/"
install -Dm644 "data/${_app_id}.desktop" -t "$pkgdir/usr/share/applications/"
install -Dm644 "data/${_app_id}.gschema.xml" -t "$pkgdir/usr/share/glib-2.0/schemas/"
install -Dm644 "data/${_app_id}.metainfo.xml" -t "$pkgdir/usr/share/metainfo/"
install -Dm644 "plugins/${pkgname%-git}"{_nautilus.py,_nautilus_compare.py} -t \
"$pkgdir/usr/share/nautilus-python/extensions/"
install -Dm644 "plugins/${pkgname%-git}_thunar.py" -t \
"$pkgdir/usr/share/thunarx-python/extensions/"
install -Dm644 "plugins/${pkgname%-git}_nemo.py" -t \
"$pkgdir/usr/share/nemo-python/extensions/"
install -Dm644 "plugins/${pkgname%-git}_caja.py" -t \
"$pkgdir/usr/share/caja-python/extensions/"
install -Dm644 data/completions/turtle_cli -t \
"$pkgdir/usr/share/bash-completion/completions/"
}
|