blob: b3f2628f20b57ddb83acd208ac3759827cbdb5ff (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: suthernfriend <public@janpeterkoenig.com>
# Contributor: RPDiep
# Contributor: Hugo Barrera <hugo@barrera.io>
# Contributor: liberodark
pkgname=tusk
pkgver=0.21.0
pkgrel=2
pkgdesc="Refined Evernote desktop app"
arch=('x86_64')
url="https://github.com/klaussinani/tusk"
license=('MIT')
makedepends=('npm')
depends=('xdg-utils' 'electron')
source=(
"$pkgname-$pkgver.tar.gz::https://github.com/klaussinani/tusk/archive/v${pkgver}.tar.gz"
"$pkgname.desktop"
"$pkgname.png"
)
sha256sums=(
'c7db7d3ef890dbc39fe13239eb6078f085d99153649c37bec99feed511135b32'
'b72cfcd35a727cb982f82d9f97f9e4330e81fbc70af47d1bc7f5baa7837a29f3'
'2e8e1f13a86bd4a8fdbd2a4a69cde6b09e035b31352ad60f5a81d61a7abfe5bf'
)
build() {
cd $srcdir/$pkgname-$pkgver
npm install --cache "${srcdir}/npm-cache"
node ./node_modules/electron-builder/out/cli/cli.js build -l dir --x64
}
package() {
cd "$srcdir/$pkgname-${pkgver}/dist/linux-unpacked"
install -Dm644 -t "${pkgdir}/usr/lib/${pkgname}" ./*.pak ./*.dat ./*.bin
install -Dm644 -t "${pkgdir}/usr/lib/${pkgname}/locales" ./locales/*
install -Dm644 -t "${pkgdir}/usr/lib/${pkgname}/resources" ./resources/*
install -Dm755 -t "${pkgdir}/usr/lib/${pkgname}" ./libffmpeg.so
install -Dm755 -t "${pkgdir}/usr/lib/${pkgname}" ./${pkgname}
# electron is required for several libs, so we use the libnode.so provided by electron itself
ln -sf "/usr/lib/electron/libnode.so" "${pkgdir}/usr/lib/${pkgname}/libnode.so"
install -dm755 "${pkgdir}/usr/bin"
ln -sf "/usr/lib/${pkgname}/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
# licenses
cd "${srcdir}/$pkgname-${pkgver}"
install -Dm644 "./license.md" "${pkgdir}/usr/share/licenses/$pkgname/LICENSE"
cd "$srcdir/$pkgname-${pkgver}/dist/linux-unpacked"
install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" ./LICENSE*
install -Dm644 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
install -Dm644 "${srcdir}/${pkgname}.png" "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
}
|