blob: b3ba6cc371cf4164307229bed923bec8d5483d1f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
# Co-Maintainer: Aaron J. Graves <linux@ajgraves.com>
pkgname=tutanota-desktop-bin
pkgver=3.112.9
pkgrel=1
pkgdesc="Official Tutanota email client"
arch=('x86_64')
url="https://tutanota.com"
license=('GPL3')
depends=('alsa-lib' 'gtk3' 'libsecret' 'nss')
makedepends=('openssl')
source=("${pkgname%-bin}-$pkgver.AppImage::https://mail.tutanota.com/desktop/${pkgname%-bin}-linux.AppImage"
"linux-sig-$pkgver.bin::https://mail.tutanota.com/desktop/linux-sig.bin"
"tutao-pub-$pkgver.pem::https://github.com/tutao/tutanota/raw/${pkgname%-bin}-release-$pkgver/tutao-pub.pem")
provides=("${pkgname%-bin}")
conflicts=("${pkgname%-bin}" "${pkgname%-bin}-linux")
replaces=("${pkgname%-bin}-linux")
sha512sums=('357197f1847ada8a3a859857c9d9fe14485134034958a87f20de845e622a6c5acf0a06ce80d7ef77340dd063a3d53aeddf1c57734f61b78b99fb6769be7a6e3b'
'10f4e54cf0c9e816d7fbf7907c7f659c04ecd4b41f07edb1d938687b044ac7fd37bd906222d0c727b40009751f5593fdb679f84f46fc7ccd79d32c01fcb763c3'
'7c6cf9f1074c08b4d38567ced95159c0809af025efe01b0163d9bb5107daabfa873064255186c071a7dc3a9177ccd0c1b2fcc8b085bdbff234965a6710b3ae45')
prepare() {
# Validate the signature against public key:
# https://tutanota.com/howto/#verify-desktop
openssl dgst -sha512 -verify tutao-pub-${pkgver}.pem -signature \
linux-sig-${pkgver}.bin "${pkgname%-bin}-$pkgver.AppImage"
chmod +x "${pkgname%-bin}-$pkgver.AppImage"
./"${pkgname%-bin}-$pkgver.AppImage" --appimage-extract
# Correct path for .desktop file
sed -i 's|Exec=AppRun|Exec=/opt/tutanota-desktop/tutanota-desktop|g' \
"squashfs-root/${pkgname%-bin}.desktop"
# Remove X-AppImage-Version
sed -i '/AppImage/d' "squashfs-root/${pkgname%-bin}.desktop"
}
package() {
find squashfs-root/{locales,resources,usr/share/icons}/ -type d -exec chmod 755 {} +
install -d "$pkgdir/opt/${pkgname%-bin}/"
cp -av squashfs-root/* "$pkgdir/opt/${pkgname%-bin}/"
chmod 4755 "$pkgdir/opt/${pkgname%-bin}/chrome-sandbox"
rm -rf "$pkgdir/opt/${pkgname%-bin}/usr/"
rm "$pkgdir/opt/${pkgname%-bin}"/{"${pkgname%-bin}".desktop,AppRun}
# Fix permisssions
chmod 644 "$pkgdir/opt/${pkgname%-bin}"/resources/app{.asar,-update.yml}
install -d "$pkgdir/usr/bin"
ln -s "/opt/${pkgname%-bin}/${pkgname%-bin}" "$pkgdir/usr/bin/"
install -Dm644 "squashfs-root/${pkgname%-bin}.desktop" -t \
"$pkgdir/usr/share/applications/"
install -d "$pkgdir/usr/share/icons/"
cp -r squashfs-root/usr/share/icons/hicolor/ "$pkgdir/usr/share/icons/"
}
|