PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73

# Maintainer: Christopher Dorrell <dorrellkc@gmail.com>
pkgname=tux-assistant
pkgver=1.0.21
pkgrel=1
pkgdesc="GTK4/Libadwaita Linux system configuration tool - simplifies post-installation setup"
arch=('any')
url="https://github.com/dorrellkc/Tux-Assistant"
license=('GPL-3.0-or-later')
depends=(
    'python'
    'python-gobject'
    'gtk4'
    'libadwaita'
    'python-requests'
    'polkit'
    'python-dbus'
    'webkit2gtk-4.1'
    'gstreamer'
    'gst-plugins-base'
    'gst-plugins-good'
    'hicolor-icon-theme'
)
optdepends=(
    'speedtest-cli: for network speed tests'
    'samba: for network file sharing'
    'gnome-shell: for GNOME extension management'
    'gst-plugins-ugly: for additional audio format support'
    'gst-plugins-bad: for additional audio format support'
)
install=tux-assistant.install
source=("$pkgname-$pkgver.tar.gz::https://github.com/dorrellkc/Tux-Assistant/archive/refs/tags/v$pkgver.tar.gz"
        "tux-assistant.install")
sha256sums=('eda39774816ee49805cf9ed58070d742a8f7d476c247c964a6d693b6e4f00b7c'
            'SKIP')

package() {
    cd "$srcdir/Tux-Assistant-$pkgver"
    
    # Install to /opt/tux-assistant
    install -dm755 "$pkgdir/opt/tux-assistant"
    cp -r tux "$pkgdir/opt/tux-assistant/"
    cp -r assets "$pkgdir/opt/tux-assistant/"
    cp -r data "$pkgdir/opt/tux-assistant/"
    cp -r scripts "$pkgdir/opt/tux-assistant/"
    install -Dm755 tux-assistant.py "$pkgdir/opt/tux-assistant/tux-assistant.py"
    install -Dm755 tux-helper "$pkgdir/opt/tux-assistant/tux-helper"
    install -Dm644 VERSION "$pkgdir/opt/tux-assistant/VERSION"
    
    # Install Tux Assistant launcher script
    install -dm755 "$pkgdir/usr/bin"
    echo '#!/bin/bash' > "$pkgdir/usr/bin/tux-assistant"
    echo 'cd /opt/tux-assistant && python tux-assistant.py "$@"' >> "$pkgdir/usr/bin/tux-assistant"
    chmod 755 "$pkgdir/usr/bin/tux-assistant"
    
    # Install Tux Tunes launcher script
    echo '#!/bin/bash' > "$pkgdir/usr/bin/tux-tunes"
    echo 'python /opt/tux-assistant/tux/apps/tux_tunes/tux-tunes.py "$@"' >> "$pkgdir/usr/bin/tux-tunes"
    chmod 755 "$pkgdir/usr/bin/tux-tunes"
    
    # Install tux-helper to /usr/bin
    install -Dm755 tux-helper "$pkgdir/usr/bin/tux-helper"
    
    # Install desktop files
    install -Dm644 data/com.tuxassistant.app.desktop "$pkgdir/usr/share/applications/com.tuxassistant.app.desktop"
    install -Dm644 data/com.tuxassistant.tuxtunes.desktop "$pkgdir/usr/share/applications/com.tuxassistant.tuxtunes.desktop"
    
    # Install icons
    install -Dm644 assets/icon.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/tux-assistant.svg"
    install -Dm644 assets/tux-tunes.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/tux-tunes.svg"
    
    # Install polkit policy
    install -Dm644 data/com.tuxassistant.helper.policy "$pkgdir/usr/share/polkit-1/actions/com.tuxassistant.helper.policy"
}