blob: 56efea5f6c4bff36b198a56575c3dce9cc77825d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Contributor: Alexander F. Rødseth <xyproto@archlinux.org>
# Contributor: Mateusz Herych <heniekk@gmail.com>
# Contributor: Sergio Jovani Guzman <moret.sjg@gmail.com>
# Contributor: royrocks <royrocks13@gmail.com>
_pkgtype=sdl2
pkgname=tuxpaint
pkgver=0.9.28
pkgrel=2
pkgdesc='Drawing program designed for young children'
arch=('x86_64')
url='https://tuxpaint.org/'
license=('GPL')
backup=('etc/tuxpaint/tuxpaint.conf')
depends=('fribidi' 'libpaper' 'librsvg' 'libimagequant' 'sdl2_image'
'sdl2_gfx' 'sdl2_mixer' 'sdl2_pango' 'sdl2_ttf')
makedepends=('gperf' 'setconf' 'imagemagick')
optdepends=('tuxpaint-stamps: more stamps'
'tuxpaint-config: configuration manager'
'python2: zh_tw font generator script')
source=("https://downloads.sourceforge.net/sourceforge/tuxpaint/$pkgname-$pkgver-$_pkgtype.tar.gz" "freetype2.patch")
sha256sums=('4f1ed9330feab324070b93630d79ced50ccc4816ab76750119f012b5d904709d' SKIP)
prepare() {
cd "$pkgname-$pkgver-$_pkgtype"
# python2 fix
for f in docs/outdated/zh_tw/mkTuxpaintIM.py fonts/locale/zh_tw_docs/maketuxfont.py; do
sed -i '0,/on/s//on2/' $f
done
# desktop shortcut categories
setconf src/tuxpaint.desktop Categories='Game;KidsGame;Graphics;RasterGraphics;'
# fullscreen by default
setconf -u src/tuxpaint.conf fullscreen=true
# location of bash completion files
setconf Makefile COMPLETIONDIR='$(DESTDIR)/usr/share/bash-completion/completions'
# no KDE4-related requirements at installation-time
setconf Makefile ARCH_INSTALL='install-man install-importscript install-bash-completion'
patch -Np1 < "../freetype2.patch"
}
build() {
make -C "$pkgname-$pkgver-$_pkgtype" PREFIX=/usr clean translations all -j1
}
package() {
make -C "$pkgname-$pkgver-$_pkgtype" \
PREFIX=/usr \
GNOME_PREFIX=/usr \
X11_ICON_PREFIX="$pkgdir/usr/share/pixmaps" \
DESTDIR="$pkgdir" \
install -j1
# bash completions
mv "$pkgdir/usr/share/bash-completion/completions/tuxpaint-completion.bash" \
"$pkgdir/usr/share/bash-completion/completions/tuxpaint"
# docs
mv "$pkgdir/usr/share/doc/$pkgname-$pkgver" \
"$pkgdir/usr/share/doc/$pkgname"
# desktop shortcut
install -Dm644 "$pkgname-$pkgver-$_pkgtype/src/$pkgname.desktop" \
"$pkgdir/usr/share/applications/$pkgname.desktop"
}
# getver: tuxpaint.org/download/source
# vim: ts=2 sw=2 et:
|