blob: a4ef8c2e5c9d5a73d28cb262ef8142196498a350 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
|
# Maintainer: Cédric Schieli <cschieli@gmail.com>
pkgname=tvheadend-satip-server-git
_gitname='tvheadend-git'
pkgver=4.3.r1857.g221c29b40
pkgrel=2
pkgdesc="TV streaming server for Linux"
arch=('i686' 'pentium4' 'x86_64' 'arm' 'armv6h' 'armv7h' 'aarch64')
url="https://tvheadend.org/"
license=('GPL3')
depends=(
'dbus'
'openssl'
'pcre2'
'uriparser'
)
makedepends=(
'git'
'python'
)
provides=('tvheadend')
conflicts=('tvheadend' 'hts-tvheadend' 'hts-tvheadend-svn' 'tvheadend-git')
install=tvheadend.install
backup=('etc/conf.d/tvheadend')
source=(
"${_gitname}::git+https://github.com/tvheadend/tvheadend.git#branch=master"
'dvb-scan-tables::git+https://git.linuxtv.org/dtv-scan-tables.git#branch=master'
'tvheadend.conf'
'tvheadend-dbus.conf'
)
md5sums=('SKIP'
'SKIP'
'57185c43bcd3512296cb23c849f4b872'
'67222bc49a82fab4189083cf993fa659')
pkgver() {
cd "${srcdir}/${_gitname}"
git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${srcdir}"
_dvbscan="${_gitname}/data/dvb-scan"
rm -rf "${_dvbscan}"
cp -a "dvb-scan-tables" "${_dvbscan}"
rm -rf "${_dvbscan}/.git"
touch "${_dvbscan}/.stamp"
}
build() {
cd "${srcdir}/${_gitname}"
./configure --prefix=/usr --mandir=/usr/share/man/man1 --release \
--python=python3 \
--enable-pie \
--disable-ccdebug \
--disable-cardclient \
--disable-cwc \
--disable-cccam \
--disable-capmt \
--disable-constcw \
--enable-linuxdvb \
--enable-satip_server \
--disable-satip_client \
--disable-hdhomerun_static --disable-hdhomerun_client \
--disable-iptv \
--enable-tsfile \
--enable-dvbscan \
--disable-timeshift \
--enable-trace \
--disable-avahi \
--enable-zlib \
--disable-ffmpeg_static --disable-libav \
--disable-libx264_static --disable-libx264 \
--disable-libx265_static --disable-libx265 \
--disable-libvpx_static --disable-libvpx \
--disable-libtheora_static --disable-libtheora \
--disable-libvorbis_static --disable-libvorbis \
--disable-libfdkaac_static --disable-libfdkaac \
--disable-libopus_static --disable-libopus \
--disable-nvenc \
--disable-vaapi \
--disable-mmal \
--disable-omx \
--disable-inotify \
--enable-epoll \
--disable-pcre --enable-pcre2 \
--enable-uriparser \
--disable-ccache \
--disable-tvhcsa \
--disable-bundle \
--disable-pngquant \
--disable-kqueue \
--enable-dbus_1 \
--disable-android \
--disable-gtimer_check \
--disalbe-slow_memoryinfo \
--enable-libsystemd_daemon \
--disable-pcloud_cache \
--disable-ddci \
--disable-cclang_threadsan \
--disable-gperftools
make
}
package() {
cd "${srcdir}/${_gitname}"
make DESTDIR="$pkgdir/" install
install -D -m 644 "${srcdir}/${_gitname}/rpm/tvheadend.service" \
"$pkgdir/usr/lib/systemd/system/tvheadend.service"
sed -i 's|/etc/sysconfig|/etc/conf.d|g' \
"$pkgdir/usr/lib/systemd/system/tvheadend.service"
install -D -m 644 "$srcdir/tvheadend.conf" "$pkgdir/etc/conf.d/tvheadend"
install -D -m 644 "$srcdir/tvheadend-dbus.conf" \
"$pkgdir/usr/share/dbus-1/system.d/tvheadend.conf"
}
|