PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

# Maintainer: T4toh <https://github.com/T4toh>
pkgname=twriter-bin
_pkgname=tWriter
pkgver=0.7.0
pkgrel=1
pkgdesc="Editor de novelas en ES/EN con conversor RAE de diálogos, gramática vía LanguageTool, export EPUB"
arch=('x86_64')
url="https://github.com/T4toh/tWriter"
license=('MIT')
depends=(
    'webkit2gtk-4.1'
    'gtk3'
    'librsvg'
    'libayatana-appindicator'
)
optdepends=(
    'pandoc: importar archivos .docx/.odt'
    'docker: correr LanguageTool local'
)
provides=('twriter')
conflicts=('twriter')
options=('!strip' '!debug')
install="${pkgname}.install"
source=("${pkgname}-${pkgver}.deb::https://github.com/T4toh/tWriter/releases/download/v${pkgver}/${_pkgname}_${pkgver}_amd64.deb")
sha256sums=('5e5c2a4375708f8d71c242f2652d457bf0d52077f72d23ad3e558b777b145dc9')

package() {
    cd "${srcdir}"
    bsdtar -xf "${pkgname}-${pkgver}.deb"
    bsdtar -xf data.tar.* -C "${pkgdir}"
    # .deb instala a /usr/, queda como está

    # Ícono en Wayland (KWin / super+alt+tab): KWin matchea el .desktop por
    # filename == app_id y es case-sensitive. webkit2gtk-4.1 es GTK3, que setea
    # el app_id Wayland desde g_get_prgname() = nombre del binario = "twriter"
    # (minúscula). El bundler de Tauri nombra el archivo según productName →
    # "tWriter.desktop" (mayúscula) y el match primario falla → ícono default.
    # Renombrar a minúscula. Name=tWriter (display) e Icon=twriter quedan igual.
    local _apps="${pkgdir}/usr/share/applications"
    if [ -f "${_apps}/tWriter.desktop" ]; then
        mv "${_apps}/tWriter.desktop" "${_apps}/twriter.desktop"
    fi
}