summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: c76dad653c082eaa856645c1f4e3b55059516123 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=uci-git
pkgver=r511.g4c8b4d6
pkgrel=1
pkgdesc="OpenWrt unified configuration interface"
arch=('i686' 'x86_64')
url="https://openwrt.org/docs/techref/uci"
license=('LGPL')
depends=('glibc' 'libubox' 'lua')
makedepends=('git' 'cmake')
provides=('uci')
conflicts=('uci')
source=("git+https://git.openwrt.org/project/uci.git")
sha256sums=('SKIP')


pkgver() {
  cd "uci"

  _rev=$(git rev-list --count --all)
  _hash=$(git rev-parse --short HEAD)
  printf "r%s.g%s" "$_rev" "$_hash"
}

build() {
  cd "uci"

  mkdir -p "_build" && cd "_build"
  cmake \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX="/usr" \
    -DCMAKE_INSTALL_LIBDIR="lib" \
    ../
  make
}

package() {
  cd "uci"

  make -C "_build" DESTDIR="$pkgdir" install
}