blob: 3dfdd1bd8ebdda7f0fa249bdc8bdbdf728ddef01 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: xsmile <sascha_r at gmx dot de>
pkgname=uefitool-git
_pkgname=uefitool
_tools=('UEFIPatch' 'UEFIReplace')
pkgver=r210.997c007
pkgrel=1
pkgdesc='UEFI firmware image viewer and editor and utilities'
arch=('any')
url='https://github.com/LongSoft/UEFITool'
license=('BSD')
depends=('qt5-base')
makedepends=('git' 'qt5-base')
provides=($_pkgname)
conflicts=($_pkgname)
source=("${_pkgname}::git+${url}.git")
md5sums=('SKIP')
pkgver() {
cd "$srcdir/$_pkgname"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
_build() {
qmake QMAKE_CFLAGS_RELEASE="$CFLAGS" QMAKE_CXXFLAGS_RELEASE="$CXXFLAGS"
make
}
build() {
# UEFITool
cd "$srcdir/$_pkgname"
_build
# Other tools
for tool in "${_tools[@]}"; do
cd "$srcdir/$_pkgname/$tool"
_build
done
}
package() {
# UEFITool
cd "$srcdir/$_pkgname"
install -D -m755 UEFITool "$pkgdir/usr/bin/$_pkgname"
# Other tools
for tool in "${_tools[@]}"; do
install -D -m755 "$tool/$tool" "$pkgdir/usr/bin/${tool,,}"
done
# Install patches.txt
install -D -m644 UEFIPatch/patches.txt "$pkgdir/usr/share/$_pkgname/patches.txt"
# License
install -Dm644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|