blob: f78f8a755dfc835c9ec09aef53d9f9b8d5c33fce (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=ufw-git
pkgver=0.36.2.r105.g76adc7a
pkgrel=1
pkgdesc="Uncomplicated firewall"
arch=('any')
url="https://launchpad.net/ufw"
license=('GPL3')
depends=('python' 'iptables')
makedepends=('git' 'python-build' 'python-installer' 'python-wheel')
provides=("ufw=$pkgver")
conflicts=('ufw')
backup=('etc/default/ufw'
'etc/ufw/after.rules'
'etc/ufw/after6.rules'
'etc/ufw/before.rules'
'etc/ufw/before6.rules'
'etc/ufw/sysctl.conf'
'etc/ufw/ufw.conf'
'etc/ufw/user.rules'
'etc/ufw/user.rules'
'etc/ufw/user6.rules')
source=("git+https://git.launchpad.net/ufw"
"ufw.service::https://gitlab.archlinux.org/archlinux/packaging/packages/ufw/-/raw/main/service")
sha256sums=('SKIP'
'SKIP')
prepare() {
cd "ufw"
# FS#28769 - move from /lib to /usr/lib
sed -i -e 's|/lib|/usr/lib|' \
-e 's|sbin|bin|g' "setup.py"
# FS#35458, FS#54110 - correct iptables location
sed -i -e 's|sbin|bin|g' "setup.py"
sed -i -e 's|sbin|bin|g' "src/util.py"
}
pkgver() {
cd "ufw"
_tag=$(git tag -l --sort -v:refname | grep -E '^v?[0-9\.]+$' | head -n1)
_rev=$(git rev-list --count $_tag..HEAD)
_hash=$(git rev-parse --short HEAD)
printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}
build() {
cd "ufw"
python \
-m build \
--wheel \
--no-isolation
}
package() {
cd "ufw"
python \
-m installer \
--destdir="$pkgdir" \
dist/*.whl
install -Dm644 "$srcdir/ufw.service" -t "$pkgdir/usr/lib/systemd/system"
}
|