blob: 5fdf876d35fa954689d762bb24ae69e2afb24fa3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=uget-git
pkgver=r628.g0c5b01f
pkgrel=2
pkgdesc="Lightweight yet powerful download manager"
arch=('i686' 'x86_64')
url="https://ugetdm.com"
license=('LGPL')
depends=('glibc' 'curl' 'gstreamer' 'gtk3' 'libnotify')
makedepends=('git' 'bash' 'intltool')
optdepends=('aria2: alternative backend')
provides=("uget=$pkgver")
conflicts=('uget')
source=("git+https://git.code.sf.net/p/urlget/uget2"
"uget-gtk.appdata.xml::https://gitlab.archlinux.org/archlinux/packaging/packages/uget/-/raw/main/uget-gtk.appdata.xml")
sha256sums=('SKIP'
'SKIP')
pkgver() {
cd "uget2"
_rev=$(git rev-list --count --all)
_hash=$(git rev-parse --short HEAD)
printf "r%s.g%s" "$_rev" "$_hash"
}
build() {
cd "uget2"
sh autogen.sh
bash configure \
--prefix="/usr"
make
}
check() {
cd "uget2"
make check
}
package() {
cd "uget2"
make DESTDIR="$pkgdir" install
install -Dm644 "$srcdir/uget-gtk.appdata.xml" -t "$pkgdir/usr/share/metainfo"
}
|