PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: fenuks
# Based on ultrastardx-git PKGBUILD

_usdx_package=WorldParty
_pkgname=ultrastardxwp
pkgname=${_pkgname}-git
pkgver=r25.9f5f917
pkgrel=1
pkgdesc="UltraStar Deluxe WorldParty is a free and open source karaoke game. It allows up to six players to sing along with music using microphones in order to score points, depending on the pitch of the voice and the rhythm of singing."
arch=("i686" "x86_64")
url="http://ultrastar-es.org"
license=("GPL")
depends=("ffmpeg2.8" "lua" "pcre" "portaudio" "sdl2" "sdl2_gfx" "sdl2_mixer" "sdl2_ttf" "sdl2_image" "sdl2_net" "sqlite" "ttf-dejavu" "ttf-freefont")
makedepends=("git" "fpc")  
optdepends=()
conflicts=("${pkgname}")
options=("!buildflags")
install=${pkgname}.install
source=("${_pkgname}.desktop"
        "${_pkgname}::git+https://github.com/ultrastares/usdxworldparty/")
md5sums=('45e724d9c3ab756ed908774daedfac24'
         'SKIP')

pkgver() {
    cd "${srcdir}/${_pkgname}"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
    cd "${srcdir}/${_pkgname}"
    chmod +x autogen.sh
    ./autogen.sh
}

build() {
    cd "${srcdir}/${_pkgname}"
    chmod +x configure
    PKG_CONFIG_PATH="/usr/lib/ffmpeg2.8/pkgconfig" ./configure --prefix=/usr
    make
}

package() {
    cd "${srcdir}/${_pkgname}"
    make install DESTDIR="$pkgdir"
    install -Dm644 "${srcdir}/${_pkgname}.desktop" "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
    install -Dm644 "${pkgdir}/usr/share/${_usdx_package}/resources/icons/${_usdx_package}.png" "${pkgdir}/usr/share/icons/${_usdx_package}.png"
}