blob: ae8115fb7dbb07711f8f82020d214eab1ceaee8d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Muflone http://www.muflone.com/contacts/english/
pkgbase=ultravnc-viewer-i18n
pkgname=()
pkgver=1.1.8.0
pkgrel=1
arch=('any')
url="http://www.uvnc.com"
license=('GPL')
depends=("ultravnc-viewer")
provides=("${pkgbase}")
conflicts=("${pkgbase}")
source=("Uvnc_translations-${pkgver}.zip"::"http://support1.uvnc.com/download/${pkgver//./}/translations.zip")
sha256sums=('77b442c4d911be9e34bd50c6aad7ec50cef8368d8e3d8f59e312385e3896c34d')
_languages=(
'ca Catalan catalan'
'de German german'
'fr French french'
'ja Japanese japanese'
'pt Portuguese portugueze'
'ru Russian russian'
'es Spanish spanish'
)
_package() {
_filename="$1"
install -m 755 -d "${pkgdir}/usr/lib/ultravnc-viewer/"
install -m 644 "translated_viewers/${_filename}.dll" "${pkgdir}/usr/lib/ultravnc-viewer/vnclang.dll"
}
for _lang in "${_languages[@]}"
do
_langarray=(${_lang})
_pkgname="${pkgbase}-${_langarray[0]}"
pkgname+=("${_pkgname}")
eval "package_${_pkgname}() {
pkgdesc='${_langarray[1]} translation for UltraVNC Viewer'
_package ${_langarray[2]}
}"
done
|