blob: a212b2fcde161ccf98fd53904f5410dee22e58a6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: Mitch <mitch at znation dot nl>
# Contributor: Red Squirrel <iam at redsquirrel87 dot com>
# Based on PMS PKGBUILD
pkgname=ums
pkgver=13.2.1
pkgrel=1
pkgdesc="Universal Media Server: a DLNA-compliant UPnP Media Server."
arch=('i686' 'x86_64' 'aarch64' 'arm' 'armv6h' 'armv7h')
url="http://www.universalmediaserver.com/"
license=('GPL2')
depends=('mplayer' 'mencoder' 'libmediainfo')
makedepends=("unzip")
optdepends=("java-runtime: Java runtime environment"
"ffmpeg: Complete solution to record, convert and stream audio and video"
"vlc: For Internet video/audio")
optdepends_x86_64=("dcraw: thumbnails creation support"
"lib32-gcc-libs: tsMuxeR support"
"lib32-glibc: tsMuxeR support")
backup=(opt/ums/UMS.conf)
source_i686=("https://github.com/UniversalMediaServer/UniversalMediaServer/releases/download/${pkgver}/UMS-${pkgver}-x86.tgz")
source_x86_64=("https://github.com/UniversalMediaServer/UniversalMediaServer/releases/download/${pkgver}/UMS-${pkgver}-x86_64.tgz")
source_aarch64=("https://github.com/UniversalMediaServer/UniversalMediaServer/releases/download/${pkgver}/UMS-${pkgver}-arm64.tgz")
source_arm=("https://github.com/UniversalMediaServer/UniversalMediaServer/releases/download/${pkgver}/UMS-${pkgver}-armel.tgz")
source_armv6h=("https://github.com/UniversalMediaServer/UniversalMediaServer/releases/download/${pkgver}/UMS-${pkgver}-armhf.tgz")
source_armv7h=(${source_armv6h})
source=('ums.desktop'
'ums.service'
'ums.timer')
sha256sums=('0cdadbabef215b6539e56755147a8f626d9f1fadfb85e2e5b7f7f1b66f1cdef9'
'1f6efefa58dde9148396bd9236a6985db0fa27f1c767067b52bfae1832f32284'
'7fd36db71f39fde3d515c697101190f979b308d910b3c4210b90422669683ab0')
sha256sums_i686=('357f1795116a66bc75a85b2b854aa501789897144b1bd20bcf5edfd6c9295555')
sha256sums_x86_64=('3068b94b48c0f56561ecfb8d7a2e6122751564b732a49bbc8b3c162690e2e36b')
sha256sums_aarch64=('f71d4cd6b671c20eb945d326c50da079e174c97aee910ddd40f5ca7d0d86448c')
sha256sums_arm=('0052ca3b2b5515d9f99361b520ac6219ba5d9e00d82907a52869ffabd6f6a29e')
sha256sums_armv6h=('34025c253f60842aa8eb3e9db03dbaf57182a6d22905a12d192f7c8e694f8138')
sha256sums_armv7h=('34025c253f60842aa8eb3e9db03dbaf57182a6d22905a12d192f7c8e694f8138')
package() {
mkdir -p "${pkgdir}/opt/ums"
mkdir "${pkgdir}/opt/ums/database"
mkdir -p "${pkgdir}/usr/bin"
cp -r "${srcdir}/ums-$pkgver"/* "${pkgdir}/opt/ums/"
touch "${pkgdir}/opt/ums/UMS.conf"
touch "${pkgdir}/opt/ums/debug.log"
chgrp users "${pkgdir}/opt/ums/UMS.conf" \
"${pkgdir}/opt/ums/debug.log" \
"${pkgdir}/opt/ums/database"
chmod g+w "${pkgdir}/opt/ums/UMS.conf" \
"${pkgdir}/opt/ums/debug.log" \
"${pkgdir}/opt/ums/database"
unzip -q -u "${srcdir}/ums-$pkgver/ums.jar" -d ums_jar
install -d -m 755 "${pkgdir}/usr/share/pixmaps"
install -D -m 644 "${srcdir}/ums_jar/resources/images/logo.png" "${pkgdir}/usr/share/pixmaps/ums.png"
install -D -m 644 "${srcdir}/ums.desktop" "${pkgdir}/usr/share/applications/ums.desktop"
install -D -m 644 "${srcdir}/ums.service" "${pkgdir}/usr/lib/systemd/system/ums@.service"
install -D -m 644 "${srcdir}/ums.timer" "${pkgdir}/usr/lib/systemd/system/ums@.timer"
install -d -m 755 "${pkgdir}/usr/bin"
ln -s "/opt/${pkgname}/UMS.sh" "${pkgdir}/usr/bin/${pkgname}"
}
|