PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

# vim:ts=4:sw=4:expandtab
# unclutter-xfixes -- rewrite of unclutter using the x11-xfixes extension.
pkgname=unclutter-xfixes-git
pkgver=v1.6.r3.g93b0f33
pkgrel=1
pkgdesc='unclutter-xfixes is a rewrite of unclutter using the x11-xfixes extension.'
arch=('i686' 'x86_64')
url='https://github.com/Airblader/unclutter-xfixes'
license=('MIT')
provides=('unclutter')
conflicts=('unclutter' 'unclutter-patched')
#groups=
depends=('libxi' 'libx11' 'libxfixes' 'libev')
makedepends=('git' 'asciidoc')
source=('git+https://github.com/Airblader/unclutter-xfixes#branch=master')
sha1sums=('SKIP')

_gitname='unclutter-xfixes'

pkgver() {
    cd "$srcdir/$_gitname"
    git describe --long --tags | sed -r 's/([^-]*-g)/r\1/;s/-/./g'
}

build() {
    cd "$_gitname"
    make all
}

package() {
    cd "$_gitname"
    make DESTDIR="$pkgdir" install
    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}