blob: e7eecc74dc6db825ab6f4d6bdc58bf7cafda672c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: Felix Golatofski <contact@xdfr.de>
# Contributor: Manuel Hüsers <manuel.huesers@uni-ol.de>
# Contributor: Alexander F Rødseth <xyproto@archlinux.org>
# Contributor: Det <nimetonmaili@gmail.com>
# Contributor: Godane aka Christopher Rogers <slaxemulator@gmail.com>
# Contributor: Michai Coman <mihai@m1x.ro>
pkgname=unetbootin
pkgver=681
pkgrel=1
arch=('x86_64')
license=('GPL')
pkgdesc='Create bootable Live USB drives'
url='https://unetbootin.github.io'
depends=('syslinux' 'p7zip' 'qt4' 'mtools' 'zenity')
makedepends=('setconf')
optdepends=('polkit: run unetbootin directly from menu'
'zenity: display an error if no authentication agent is found')
source=("https://github.com/unetbootin/unetbootin/archive/${pkgver}.tar.gz"
'org.archlinux.pkexec.unetbootin.policy'
'unetbootin.sh')
sha256sums=('ec62a6321c39203a096d6a778b2f1518da815ece135e5eb95ba1e42e28ec240a'
'fa9bb53d90cb10a0ab8dd317ed6a3506b228b0e26ed2ed8b108b5990f641641a'
'6399c6a44b270a4ec67a36e3914c7c2f47a9008efb0133a33f92d9ad4284cc57')
prepare() {
cd "${pkgname}-${pkgver}/src/${pkgname}"
setconf unetbootin.desktop Exec /usr/bin/unetbootin
}
build() {
cd "${pkgname}-${pkgver}/src/${pkgname}"
./build-nostatic
}
package() {
cd "${pkgname}-${pkgver}/src/${pkgname}"
install -d "${pkgdir}/usr/share/${pkgname}"
install -m644 "${pkgname}"_*.qm "${pkgdir}/usr/share/${pkgname}/"
install -Dm755 "${pkgname}" "${pkgdir}/usr/bin/${pkgname}.elf"
# Application shortcut
install -Dm644 "${pkgname}.desktop" \
"${pkgdir}/usr/share/applications/${pkgname}.desktop"
for i in 16 22 24 32 48 256; do
install -Dm644 "${pkgname}_${i}.png" \
"${pkgdir}/usr/share/icons/hicolor/${i}x${i}/apps/${pkgname}.png"
done
cd "$srcdir"
install -m755 "${pkgname}.sh" "${pkgdir}/usr/bin/${pkgname}"
# Polkit policy
install -Dm644 'org.archlinux.pkexec.unetbootin.policy' \
"${pkgdir}/usr/share/polkit-1/actions/org.archlinux.pkexec.unetbootin.policy"
}
|