blob: 1445d8b747a07da22b7c07586f5f684e11c810c1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: SandaruKasa <sandarukasa plus aur at ya dot ru>
# Contributor Rhinoceros <https://aur.archlinux.org/account/rhinoceros>
# Contributor: Andreas Hübner <andhu@gmx.de>
_pkgname='unicode'
pkgname="${_pkgname}-git"
pkgver=2.9.r15.g13d2469
pkgrel=1
pkgdesc='Display unicode character properties on the command line'
url='https://github.com/garabik/unicode'
arch=('any')
license=('GPL3')
makedepends=("git" "python-setuptools")
depends=('python' 'unicode-character-database')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=("${_pkgname}::git+${url}.git")
sha256sums=('SKIP')
pkgver() {
cd "${_pkgname}"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${_pkgname}"
git clean -dfx
}
build() {
cd "${_pkgname}"
python setup.py build
}
package() {
cd "${_pkgname}"
python setup.py install --root="$pkgdir" --optimize=1
}
|