PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Maintainer: Frederik Schwan <frederik dot schwan at linux dot com>
# Contributor: Sébastien "Seblu" Luttringer <seblu@archlinux.org>

pkgname=unifi
pkgver=5.6.29
pkgrel=1
pkgdesc='Centralized management system for Ubiquiti UniFi AP'
arch=('any')
url='https://community.ubnt.com/unifi'
# We are allowed to ship the software in our repository
# https://mailman.archlinux.org/mailman/private/arch-dev/2014-August/015690.html
license=('custom')
depends=('mongodb' 'java-runtime-headless' 'fontconfig')
conflicts=('tomcat-native')
source=("UniFi-$pkgver.zip::https://dl.ubnt.com/unifi/$pkgver/UniFi.unix.zip"
        'unifi.service'
        'unifi.sysusers'
        'LICENSE')
sha512sums=('84a1aa0638c44d76b204b460480f2702219bafc8ba931d3062de55380375751f7a12d9408eb0599956aa21bcdca6fb6e1d4a8a70a068e6ecc78f14c1f1b0421a'
            '4b77e480dac9acef58e2d8f088491aa056a55edc9ca613c1b707d53ca802579513082e7c16f5a59689813609b97c2391253c99d77709be4a536abb683e5106ed'
            '0fdd04112236bb3f4d96e4e1c43e0a9d97412831b44837466d70e15521336275a0496dbd47dd28873dc85ba4982ef2234e31c78146eb45c20b158dadf2cec7b8'
            '22e0a4d5be7645e7f1dd760a1b93fa5a49a7e92ce6f23f2a7d0f72043cd0be057bd3faecabd1d3048ecf93480b47d278926b99b5abc17ecbe91a5b15763f0a9c')

package() {
    # lib
    install -dm755 "${pkgdir}/usr/lib/unifi"
    cp -r UniFi/{bin,dl,lib,webapps} "${pkgdir}/usr/lib/unifi"
    rm -r "${pkgdir}/usr/lib/unifi/lib/native"

    # data
    install -dm750 "${pkgdir}/var/lib/unifi"
    for _d in data run work; do
        install -dm750 "${pkgdir}/var/lib/unifi/$_d"
        ln -s "../../../var/lib/unifi/$_d" "${pkgdir}/usr/lib/unifi/$_d"
    done
    chown -R 113:113 "${pkgdir}/var/lib/unifi"

    # log
    install -dm750 "${pkgdir}/var/log/unifi"
    ln -s ../../../var/log/unifi "${pkgdir}/usr/lib/unifi/logs"
    chown -R 113:113 "${pkgdir}/var/log/unifi"

    # readme
    install -Dm644 UniFi/readme.txt "${pkgdir}/usr/share/doc/${pkgname}/README"

    # license
    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

    # systemd
    install -Dm644 ${pkgname}.service "${pkgdir}/usr/lib/systemd/system/${pkgname}.service"
    install -Dm644 ${pkgname}.sysusers "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
}