blob: 1d80f79c1d71798585d89235863f0c052b38a241 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Donald Webster (fryfrog@gmail.com)
pkgname=unifi-video
pkgver=3.6.0
pkgrel=3
pkgdesc="Centralized management system for Ubiquiti UniFi Surveillance Cameras"
arch=('x86_64')
url="https://www.ubnt.com/"
license=('custom')
depends=('mongodb' 'jre8-openjdk-headless' 'java-jsvc' 'lsb-release')
conflicts=('unifi-video-beta')
install=unifi-video.install
source=("http://dl.ubnt.com/firmwares/unifi-video/${pkgver}/unifi-video_${pkgver}~Ubuntu16.04_amd64.deb"
'unifi-video.service'
'unifi-video.sysusers'
'unifi-video.patch')
sha256sums=('1c2963fd4071e0f25649c37b833fbaa41f36e51138a6e4eec9228e4737c731bd'
'9df948b046347c25e7c83e4837284ef63d9f8d3f28daa20a6c36e203e3ebfdb3'
'90fb2f826a70d3b7815cd6a2253c2af6754c17504be28ef92ee223bd02093730'
'87f685b8f43a0cf3c03297aa29b7db5a7536f1e245b792370b2b625689d6c69b')
package() {
msg2 "Extracting unifi-video..."
tar xf "${srcdir}/data.tar.gz" -C "${pkgdir}"/
msg2 "Removing unwanted /etc with init.d script and sudoers file..."
rm -r "${pkgdir}/etc"
msg2 "Moving /usr/sbin -> /usr/bin..."
mv "${pkgdir}/usr/sbin" "${pkgdir}/usr/bin"
msg2 "Making unifi-video executable..."
chmod +x "${pkgdir}/usr/bin/unifi-video"
msg2 "Patching out ulimit..."
cd "${pkgdir}/usr/bin"
patch -N < "${srcdir}/unifi-video.patch"
msg2 "Installing systemd files..."
install -D -m 644 "${srcdir}/unifi-video.service" "${pkgdir}/usr/lib/systemd/system/unifi-video.service"
install -D -m 644 "${srcdir}/unifi-video.sysusers" "${pkgdir}/usr/lib/sysusers.d/unifi-video.conf"
msg2 "Creating directories..."
mkdir -p "${pkgdir}/usr/lib/unifi-video/logs" "${pkgdir}/usr/lib/unifi-video/work"
}
# vim:set ts=2 sw=2 et:
|