PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=unittestpp-git
pkgver=2.0.0.r30.g10e50ad
pkgrel=1
pkgdesc="A lightweight unit testing framework for C++"
arch=('i686' 'x86_64')
url="https://github.com/unittest-cpp/unittest-cpp/"
license=('MIT')
makedepends=('git' 'cmake')
provides=("unittestpp=$pkgver")
conflicts=('unittestpp')
options=('staticlibs')
source=("git+https://github.com/unittest-cpp/unittest-cpp.git")
sha256sums=('SKIP')


pkgver() {
  cd "unittest-cpp"

  _tag=$(git tag -l --sort -v:refname | grep -E '^v?[0-9\.]+$' | head -n1)
  _rev=$(git rev-list --count $_tag..HEAD)
  _hash=$(git rev-parse --short HEAD)
  printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}

build() {
  cd "unittest-cpp"

  CXXFLAGS="$CXXFLAGS -ffat-lto-objects" \
  cmake \
    -B "_build" \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX="/usr" \
    -DUTPP_AMPLIFY_WARNINGS=OFF \
    ./
  make -C "_build"
}

package() {
  cd "unittest-cpp"

  make -C "_build" DESTDIR="$pkgdir" install
  install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/unittestpp"
}