blob: 14263a5030cb2955516a9ff2304a7a81e5d0df95 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: Juraj Fiala <doctorjellyface at riseup dot net>
# Maintainer: Florian Walch <florian+aur at fwalch dot com>
# Maintainer: Leonard König <leonard.r.koenig at googlemail dot com>
# Maintainer: Oscar Morante <spacepluk at gmail dot com>
pkgname=unity-editor
_version=5.1.0
_build=f3
_buildtag=2015082501
pkgver=${_version}${_build}+${_buildtag}
pkgrel=5
pkgdesc="The world's most popular development platform for creating 2D and 3D multiplatform games and interactive experiences."
arch=('x86_64')
url='https://unity3d.com/'
license=('custom')
depends=('desktop-file-utils'
'xdg-utils'
'gcc-multilib'
'libgl'
'glu'
'nss'
'libpng12'
'libxtst'
'monodevelop')
makedepends=('elinks'
'libxml2')
optdepends=('ffmpeg: for WebGL exporting'
'nodejs: for WebGL exporting'
'java-runtime: for WebGL exporting'
'gzip: for WebGL exporting'
'java-environment: for Android and Tizen exporting'
'android-sdk: for Android Remote'
'android-udev: for Android Remote')
conflicts=('unity3d')
replaces=('unity3d')
install="${pkgname}.install"
source=("http://download.unity3d.com/download_unity/unity-editor-installer-${pkgver}.sh"
'EULA'
'unity-editor'
'monodevelop-unity')
noextract=("unity-editor-installer-${pkgver}.sh")
sha256sums=('bf73e7693ae15b271dbbd55010eb33fae3400b964fa4b70289bd5a17d19d5493'
'3e0f6faad2cae20ae2784256b0f5525fc69897a889d696aa5d748db2fe8c6a14'
'a03aaf639c6ba56a0ef03a591f0f629a3e015a3a3c6999ecc0feb6b2284c901b'
'7309ac206fbb6eb5f1a073bf22e2571e1a574410ab410138a19fb66c3eee21e3')
options=(!strip)
PKGEXT='.pkg.tar' # Prevent compressing of the final package
build() {
yes | fakeroot sh "unity-editor-installer-${pkgver}.sh"
}
package() {
local extraction_dir="${srcdir}/unity-editor-${_version}${_build}"
mkdir -p "${pkgdir}/opt/Unity"
cp -a "${extraction_dir}/." "${pkgdir}/opt/Unity"
# Remove bundled libresolv.so.2 for the time being (workarounds network problems)
rm "${pkgdir}/opt/Unity/Editor/Data/Tools/libresolv.so.2"
# Use the launch scripts in the .desktop files
sed -i "/^Exec=/c\Exec=/usr/bin/unity-editor" "${extraction_dir}/unity-editor.desktop"
sed -i "/^Exec=/c\Exec=/usr/bin/monodevelop-unity" "${extraction_dir}/unity-monodevelop.desktop"
install -Dm644 -t "${pkgdir}/usr/share/applications" "${extraction_dir}/unity-editor.desktop" \
"${extraction_dir}/unity-monodevelop.desktop"
install -Dm644 -t "${pkgdir}/usr/share/icons/hicolor/256x256/apps" "${extraction_dir}/unity-editor-icon.png"
install -Dm644 -t "${pkgdir}/usr/share/icons/hicolor/48x48/apps" "${extraction_dir}/unity-monodevelop.png"
install -Dm755 -t "${pkgdir}/usr/bin" "${srcdir}/unity-editor"
install -Dm755 -t "${pkgdir}/usr/bin" "${srcdir}/monodevelop-unity"
install -Dm644 "${srcdir}/EULA" "${pkgdir}/usr/share/licenses/${pkgname}/EULA"
}
# vim:set sw=2 sts=2 et:
|