blob: de8b8bd355bb857b2581400e91eb5fe2065159f5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: Oscar Morante <spacepluk at gmail dot com>
_prefix=/opt/UnityBeta
pkgname=unity-editor-beta
pkgver=2019.1.0a12
pkgrel=1
pkgdesc="The world's most popular development platform for creating 2D and 3D multiplatform games and interactive experiences."
arch=('x86_64')
url='https://unity3d.com/'
license=('custom')
depends=('desktop-file-utils'
'xdg-utils'
'gcc-libs'
'lib32-gcc-libs'
'gconf'
'libgl'
'glu'
'nss'
'libpng12'
'libxtst'
'libpqxx'
'npm'
'intel-tbb'
'gtk3')
optdepends=("${pkgname}-doc"
"${pkgname}-android"
"${pkgname}-ios"
"${pkgname}-mac"
"${pkgname}-webgl"
"${pkgname}-windows"
"${pkgname}-facebook"
"visual-studio-code-bin")
source=("2019.1.0a12.tar.xz::https://beta.unity3d.com/download/5175bce2e5d4/LinuxEditorInstaller/Unity.tar.xz"
"${pkgname}"
"${pkgname}.desktop"
"${pkgname}-icon.png"
"eula.txt")
md5sums=("eee04fe02f11b9c5a930ecf8de99b0c0"
'a0705606b7f36a6f1e4bc01be16336b1'
'03837b6962d1050bbaf29b76e0f257e3'
'723f9e556821810682a6d1f4be540a74'
'24f6741eba3d591a0761f3c92e3cc1f7')
options=(!strip)
PKGEXT='.pkg.tar' # Prevent compressing of the final package
package() {
install -d "${pkgdir}/${_prefix}"
mv "${srcdir}/Editor" "${pkgdir}/${_prefix}"
# HACK: fixes WebGL builds by adding a symlink (python -> python2) to the PATH
ln -s /usr/bin/python2 "${pkgdir}${_prefix}/Editor/python"
# Fix permissions
find "${pkgdir}${_prefix}/Editor/Data" -type d -exec chmod ga+rx {} \;
# Add version to desktop file
sed -i "/^Version=/c\Version=${_version}${_build}" "${srcdir}/${pkgname}.desktop"
install -Dm644 -t "${pkgdir}/usr/share/applications" "${srcdir}/${pkgname}.desktop"
install -Dm644 -t "${pkgdir}/usr/share/icons/hicolor/256x256/apps" "${srcdir}/${pkgname}-icon.png"
install -Dm755 -t "${pkgdir}/usr/bin" "${srcdir}/${pkgname}"
install -Dm644 "${srcdir}/eula.txt" "${pkgdir}/usr/share/licenses/${pkgname}/eula.txt"
}
|