blob: 39842173a670eb762f1fc137a2de3b6fe05d9614 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Jakob Gahde <j5lx@fmail.co.uk>
# Contributor: VargArch <roels.jorick@gmail.com>
# Contributor: zsrkmyn
# Contributor: marsam
_gitname=ctags
pkgname=universal-ctags-git
pkgver=0.r6046.e65e91a2
pkgrel=1
pkgdesc="Multilanguage reimplementation of the Unix ctags utility"
arch=('i686' 'x86_64')
url="https://ctags.io/"
license=('GPL')
depends=('libxml2' 'jansson' 'libyaml' 'libseccomp')
makedepends=('git' 'python-docutils')
provides=('ctags')
conflicts=('ctags')
source=("git+https://github.com/universal-ctags/ctags.git")
md5sums=('SKIP')
pkgver() {
cd "${srcdir}/${_gitname}"
printf "0.r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd "${srcdir}/${_gitname}"
./autogen.sh
./configure --prefix=/usr \
--libexecdir=/usr/lib \
--sysconfdir=/etc
make
}
check() {
cd "${srcdir}/${_gitname}"
mkdir "${srcdir}/testhome"
HOME="${srcdir}/testhome" make -k check
}
package() {
cd "${srcdir}/${_gitname}"
make DESTDIR="${pkgdir}" install
}
|