blob: 8ca0f08c76c7ed8f0cdbd40d55320eec14c221ad (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Maintainer: SelfRef <arch@selfref.dev>
_pkgbase=unsloth
pkgname="$_pkgbase-git"
pkgver=0.1.37.beta.r41.g726abd5
pkgrel=1
pkgdesc='Web UI for training and running open models locally'
arch=('x86_64')
url='https://github.com/unslothai/unsloth'
license=('Apache-2.0' 'AGPL-3.0-or-later')
depends=(
'python'
'python-typer'
'python-pydantic'
'python-yaml'
'python-nest-asyncio'
)
makedepends=(
'git'
'python-build'
'python-installer'
'npm'
)
provides=("$_pkgbase")
conflicts=("$_pkgbase")
install=setup.install
source=(
"$_pkgbase::git+https://github.com/unslothai/unsloth.git"
"unsloth-setup"
)
sha256sums=('SKIP'
'14444b022bd50269d474df655e74c3309959c1bd312214b7b431ed341b26a222')
pkgver() {
cd "$_pkgbase"
git describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
}
build() {
# Build the Vite/TypeScript frontend
cd "$_pkgbase/studio/frontend"
npm install
npm run build
cd "$srcdir/$_pkgbase"
python -m build --wheel
}
package() {
cd "$_pkgbase"
python -m installer --destdir="$pkgdir" dist/*.whl
# Ship install.sh so users can run it post-install to create the per-user
# studio venv (~/.unsloth/studio/unsloth_studio) with PyTorch etc.
install -Dm755 install.sh "$pkgdir/usr/share/$_pkgbase/install.sh"
# Convenience wrapper to run the setup installer from PATH.
install -Dm755 "$srcdir/unsloth-setup" "$pkgdir/usr/bin/unsloth-setup"
}
|