blob: f604d87135d98f01cbe809625862b03b16a40310 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Brian Bidulock <bidulock@openss7.org>
# Contributor: Jan de Groot <jgc@archlinux.org>
pkgname=upower-git
_pkgname=upower
pkgver=0.99.3.r34.g3e49e65
pkgrel=1
pkgdesc="Abstraction for enumerating power devices, listening to device events and querying history and statistics"
arch=('i686' 'x86_64')
url="http://upower.freedesktop.org"
license=('GPL')
depends=('systemd' 'libusb' 'dbus-glib' 'libimobiledevice' 'libgudev')
makedepends=('intltool' 'docbook-xsl' 'gobject-introspection' 'python2')
provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname")
backup=('etc/UPower/UPower.conf')
source=("$pkgname::git://anongit.freedesktop.org/upower")
md5sums=('SKIP')
pkgver() {
cd $pkgname
git describe --long --tags | sed -E 's/^[^0-9]*//;s/([^-]*-g)/r\1/;s/[-_]/./g'
}
prepare() {
cd $pkgname
NOCONFIGURE=true ./autogen.sh
}
build() {
cd $pkgname
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--libexecdir=/usr/lib/$_pkgname \
--disable-static
make
}
package() {
cd $pkgname
make DESTDIR="$pkgdir" install
}
|