blob: 03a1a992f089e637587448f316531fe667cecc8f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Kevin MacMartin <prurigro@gmail.com>
# Contributor: bionade24
# Contributor: vivaeltopo
# Contributor: aliu
_pkgname=upscayl
pkgname=$_pkgname-bin
pkgver=2.9.9
pkgrel=2
pkgdesc='Free and Open Source AI Image Upscaler'
url='https://github.com/upscayl/upscayl'
license=('AGPL3')
arch=('x86_64')
depends=('libasound.so' 'gtk3' 'libvips' 'nodejs' 'nss' 'openjpeg2')
makedepends=('unzip')
provides=($_pkgname)
conflicts=($_pkgname)
options=('!strip')
noextract=("upscayl-${pkgver}-linux.zip")
source=("https://github.com/upscayl/upscayl/releases/download/v${pkgver}/upscayl-${pkgver}-linux.zip")
sha512sums=('06f4a4439cbd7df9dba151530a42368f08d0fab5b145c1563a080aac1aac4b4a094a135f76b381b6a94a7d66d1071dccc647e9c69912cacfe3fe3157a211bf1c')
prepare() {
cd "$srcdir"
unzip upscayl-${pkgver}-linux.zip -x resources/128x128.png -d upscayl
printf '%s\n' 'Icon=org.upscayl.Upscayl' >> "$_pkgname"/resources/org.upscayl.Upscayl.desktop
}
package() {
cd "$srcdir"
# Licenses
install -dm755 "$pkgdir"/usr/share/licenses/$pkgname
mv "$_pkgname"/LICENSE* "$pkgdir"/usr/share/licenses/$pkgname/
# XDG Launcher
install -dm755 "$pkgdir"/usr/share/applications
install -dm755 "$pkgdir"/usr/share/pixmaps
mv "$_pkgname"/resources/org.upscayl.Upscayl.desktop "$pkgdir"/usr/share/applications/
mv "$_pkgname"/resources/512x512.png "$pkgdir"/usr/share/pixmaps/org.upscayl.Upscayl.png
# App directory
install -dm755 "$pkgdir"/opt
mv "$_pkgname" "$pkgdir"/opt/
# Symlink in $PATH
install -dm755 "$pkgdir/usr/bin"
ln -s /opt/$_pkgname/$_pkgname "$pkgdir/usr/bin/$_pkgname"
}
|