PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Maintainer: TwoFinger
# Contributor: ObscureScience <curvedreality at gmail dot com>

pkgname=urweb-git
_pkgname=urweb
pkgver=20240308.55a881ff
pkgrel=1
pkgdesc='Full stack web framework based on a functional programming language'
url='http://www.impredicative.com/ur/'
arch=(i686 x86_64)
license=(BSD-3-Clause)
depends=()
optdepends=(postgresql mariadb sqlite)
makedepends=(mlton openssl git)
source=(git+https://github.com/urweb/urweb.git)
md5sums=(SKIP)

provides=($_pkgname)
conflicts=($_pkgname)

pkgver() {
	cd "$srcdir"/$_pkgname
	git log -1 --format='%cd.%h' --date=short | tr -d -
}

prepare() {
	cd "$srcdir"/$_pkgname
	./autogen.sh
	./configure --without-emacs --prefix=/usr
}

build() {
	cd "$srcdir"/$_pkgname
	make
}

package() {
	cd "$srcdir"/$_pkgname
	make PREFIX=/usr DESTDIR="$pkgdir" install
	install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$_pkgname/LICENSE
	install -Dm644 README.md "$pkgdir"/usr/share/doc/$_pkgname/README
}