summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 48bf00e47d7a55b24110aaacd4605bce225a7afd (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
# Maintainer: Bhushan Shah <bshah@kde.org>
# Contributor: Gustavo Alvarez <sl1pkn07@gmail.com>

pkgname=user-manager-git
pkgver=r274.e74e910
pkgrel=1
pkgdesc="A simple system settings module to manage the users of your system (GIT version)"
url='https://projects.kde.org/user-manager'
arch=('i686' 'x86_64')
license=('GPL' 'LGPL' 'FDL')
depends=('accountsservice' 'libpwquality' 'kdelibs4support')
makedepends=('extra-cmake-modules' 'kdoctools' 'git')
conflicts=('kcm-user-manager' 'user-manager')
provides=('kcm-user-manager' 'user-manager')
replaces=('kcm-user-manager-git')
groups=('plasma')
source=('git://anongit.kde.org/user-manager')
sha1sums=('SKIP')

pkgver() {
  cd user-manager
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../user-manager \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DLIB_INSTALL_DIR=lib \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
    -DBUILD_TESTING=OFF
  make
}

package() {
  make -C build DESTDIR="${pkgdir}" install
}