PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

# Maintainer: Imperator Storm <ImperatorStorm11@protonmail.com>
# Contributor: Sunny <brainworms2002 at gmail dot com>

pkgname="uzdoom-appimage"
pkgver=5.0.0
#_srctag=${pkgver%.*}-${pkgver##*.}
_srctag=${pkgver}
pkgrel=1
pkgdesc="UZDoom is a feature centric port for all Doom engine games, based on GZDoom, adding an advanced renderer and powerful scripting capabilities (Appimage)"
url="https://github.com/UZDoom/UZDoom"
license=("GPL-3.0-or-later" "BSD-3-Clause" "LGPL-3.0-or-later" "LicenseRef-DUMB" "bzip2-1.0.6" "0BSD" )
arch=("x86_64")
provides=("uzdoom")
conflicts=("uzdoom")
depends=(zlib glibc squashfuse)
source=(Linux-UZDoom-$_srctag.AppImage::"https://github.com/UZDoom/UZDoom/releases/download/$_srctag/Linux-UZDoom-Release-x86_64.AppImage")
sha256sums=('2cd58632d9ef88bd7a92f6b4eac1fc61861ab00528c24f700fcf59e82a4fefa4')
options=(!strip !debug)
build() {
  chmod +x "Linux-UZDoom-$_srctag.AppImage"
  "./Linux-UZDoom-$_srctag.AppImage" --appimage-extract
}

package() {
  install -Dm755 "Linux-UZDoom-$_srctag.AppImage" "$pkgdir/usr/bin/uzdoom"
  install -Dm644 "$srcdir/squashfs-root/org.zdoom.UZDoom.svg" -t "$pkgdir/usr/share/pixmaps/"
  install -Dm644 "$srcdir/squashfs-root/org.zdoom.UZDoom.desktop" -t "$pkgdir/usr/share/applications/"
  install -Dm644 "$srcdir/squashfs-root/usr/share/doc/uzdoom/licenses/"* -t "$pkgdir/usr/share/licenses/$pkgname/"
  rm -rf "$srcdir/squashfs-root/usr/share/doc/uzdoom/licenses/"
  install -Dm644 "$srcdir/squashfs-root/usr/share/doc/uzdoom/"* -t "$pkgdir/usr/share/doc/uzdoom"
  ln -s "/usr/share/licenses/$pkgname/" "$pkgdir/usr/share/doc/uzdoom/licenses"
  install -Dm644 "$srcdir/squashfs-root/usr/share/metainfo/"* -t "$pkgdir/usr/share/metainfo/uzdoom"
  install -Dm644 "$srcdir/squashfs-root/usr/share/mime/packages/org.zdoom.UZDoom-mime.xml" -t "$pkgdir/usr/share/mime/packages/"
  install -Dm644 "$srcdir/squashfs-root/usr/share/mime/application/x-doom-pk"{3,7}".xml" -t "$pkgdir/usr/share/mime/application/"
  install -Dm644 "$srcdir/squashfs-root/usr/share/mime/application/x-doom-wad.xml" -t "$pkgdir/usr/share/mime/application/"
}