blob: 1182da5081a8754cb8a2948f225304c551816573 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
|
pkgname=v2ray-rs
pkgver=0.20.0
pkgrel=1
pkgdesc="Linux desktop GUI for v2ray/xray/sing-box proxy management"
arch=('x86_64')
url="https://github.com/victorzhuk/v2ray-rs"
license=('Apache-2.0')
depends=('gtk4' 'libadwaita' 'dbus' 'libcap')
makedepends=('rust' 'cargo')
optdepends=(
'v2ray: V2Ray proxy backend'
'xray: Xray proxy backend'
'sing-box: sing-box proxy backend'
'polkit: one-time TUN privilege grant via pkexec'
)
install=v2ray-rs.install
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha256sums=('a360c4b96f530da32cfaad736caabc37c84afbf09198702e766c6ea66ae1747d')
prepare() {
cd "$pkgname-$pkgver"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "$pkgname-$pkgver"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release -p v2ray-rs-ui -p v2ray-rs-netctl -p v2ray-rs-run
}
package() {
cd "$pkgname-$pkgver"
install -Dm755 "target/release/v2ray-rs-ui" "$pkgdir/usr/bin/v2ray-rs"
# Privileged TUN helpers. The install hook creates the `v2ray-rs` group,
# restricts these to it (netctl 0750 + cap_net_admin, run 4750 setuid), and
# creates the bypass user. Modes here are the pre-hook defaults.
install -Dm755 "target/release/v2ray-rs-netctl" "$pkgdir/usr/bin/v2ray-rs-netctl"
install -Dm4755 "target/release/v2ray-rs-run" "$pkgdir/usr/bin/v2ray-rs-run"
install_icon "assets/v2ray-rs.svg" \
"crates/ui/icons/hicolor/scalable/apps/com.github.v2ray-rs.svg" \
"$pkgdir/usr/share/icons/hicolor/scalable/apps/com.github.v2ray-rs.svg"
install_optional "assets/v2ray-rs.png" \
"$pkgdir/usr/share/icons/hicolor/256x256/apps/com.github.v2ray-rs.png"
install_icon "crates/ui/icons/hicolor/symbolic/apps/com.github.v2ray-rs-symbolic.svg" \
"assets/v2ray-rs-symbolic.svg" \
"$pkgdir/usr/share/icons/hicolor/symbolic/apps/com.github.v2ray-rs-symbolic.svg"
install_icon "assets/com.github.v2ray-rs.desktop" \
"crates/ui/assets/com.github.v2ray-rs.desktop" \
"$pkgdir/usr/share/applications/com.github.v2ray-rs.desktop"
local lang
for lang in en_US ru_RU; do
install -Dm644 "locale/$lang/LC_MESSAGES/v2ray-rs.mo" \
"$pkgdir/usr/share/locale/$lang/LC_MESSAGES/v2ray-rs.mo"
done
install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
install_icon() {
local primary=$1
local fallback=$2
local dest=$3
if [[ -f "$primary" ]]; then
install -Dm644 "$primary" "$dest"
return
fi
if [[ -f "$fallback" ]]; then
install -Dm644 "$fallback" "$dest"
return
fi
echo "Missing icon asset: $primary or $fallback" >&2
return 1
}
install_optional() {
local src=$1
local dest=$2
if [[ -f "$src" ]]; then
install -Dm644 "$src" "$dest"
fi
}
|