blob: f44143ee0f4c5a09d9a5f8efb05ec0a883f6652f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Maintainer: Torleif Skår <torleif.skaar AT gmail DOT com>
_pkgname=vacask
pkgname="${_pkgname}-git"
pkgver=0.3.3.r0.g8729bbf
pkgrel=1
pkgdesc="Verilog-A Circuit Analysis Kernel is an analog circuit simulator"
arch=(
'x86_64'
'aarch64'
)
url="https://codeberg.org/arpadbuermen/VACASK"
license=('AGPL-3.0-or-later')
depends=(
'suitesparse'
'boost-libs'
'glibc'
'libstdc++'
'libgcc'
'libgomp'
)
makedepends=(
'git'
'gcc'
'cmake'
'ninja'
'boost'
'bison'
'flex'
'tomlplusplus'
'openvaf-r'
)
checkdepends=(
'python'
'python-numpy'
'python-scipy'
)
optdepends=(
'python-matplotlib: For plotting the individual tests'
)
conflicts=("${_pkgname}")
options=()
source=("${_pkgname}::git+${url}")
b2sums=('SKIP')
pkgver() {
cd "${_pkgname}"
git describe --long --tags --abbrev=7 | sed 's/^_//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
local cmake_options=(
-B build
-S "${_pkgname}"
-W no-dev
-D CMAKE_BUILD_TYPE=None
-D CMAKE_INSTALL_PREFIX=/usr
)
cmake "${cmake_options[@]}"
cmake --build build
}
check() {
ctest --test-dir build --output-on-failure
}
package() {
DESTDIR="${pkgdir}" cmake --install build
# Remove redudant openvaf-r
rm "${pkgdir}/usr/bin/openvaf-r"
}
# vim: ts=4 sw=4 et:
|