PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Maintainer: Giuseppe Calà <gcala (at) mailbox (dot) org>

pkgname=vakzination-git
_pkgname=vakzination
pkgver=r109.8484ef7
pkgrel=1
pkgdesc="Vakzination manages your health certificates like vaccination, test, and recovery certificates"
arch=(x86_64 aarch64)
url="https://invent.kde.org/plasma-mobile/vakzination"
license=(LGPL)
provides=($_pkgname)
conflicts=($_pkgname)
depends=(qt5-declarative kcodecs karchive qt5-svg khealthcertificate kitinerary kirigami2)
makedepends=(git extra-cmake-modules prison)
source=("git+https://invent.kde.org/plasma-mobile/vakzination.git")
sha256sums=('SKIP')

pkgver() {
  cd $_pkgname
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../$_pkgname \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DBUILD_TESTING=OFF
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}