summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: ee1ea8c8797bae862ee9fe7e0fde07d06bfa34b8 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
# Maintainer: Felix Schindler <aur at felixschindler dot net>
# Contributor: Dan McGee <dan@archlinux.org>
# Contributor: Allan McRae <allan@archlinux.org>
#
# There is a bug in valgrind 3.13 which arises when used from qtcreater, see
# https://stackoverflow.com/questions/45531851/valgrind-in-qt-creator#45551442

pkgname=valgrind312
_pkgname=valgrind
pkgver=3.12.0
pkgrel=3
pkgdesc='A tool to help find memory-management problems in programs (version 3.12.0)'
arch=(i686 x86_64)
license=(GPL)
url='http://valgrind.org/'
depends=('glibc=2.28' 'perl')
makedepends=(gdb openmpi)
optdepends=('openmpi: MPI support')
options=(!emptydirs)
source=(http://valgrind.org/downloads/$_pkgname-$pkgver.tar.bz2)
sha1sums=('7a6878bf998c60d1e377a4f22ebece8d9305bda4')
provides=("${_pkgname}=${pkgver}")
conflicts=("$_pkgname")
replaces=("$_pkgname")

build() {
  # valgrind does not like stack protector flags
  CPPFLAGS=${CPPFLAGS/-D_FORTIFY_SOURCE=2/}
  CFLAGS=${CFLAGS/-fstack-protector-strong/}
  CXXFLAGS=${CXXFLAGS/-fstack-protector-strong/}

  cd $_pkgname-$pkgver
  ./configure --prefix=/usr --mandir=/usr/share/man --with-mpicc=mpicc
  make
}

package() {
  cd $_pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}