blob: ace7dcb33d127103ad2ce8ea715116d9c9757cfb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: witchymary
_plug=bestsource
pkgname=vapoursynth-plugin-${_plug}-git
pkgver=r272.d676835
pkgrel=2
pkgdesc="Plugin for Vapoursynth: ${_plug} (GIT version)"
arch=('x86_64')
url='https://forum.doom9.org/showthread.php?p=1972253'
license=('MIT')
depends=('vapoursynth'
'libavcodec.so'
'libavformat.so'
'jansson'
)
makedepends=('git'
'meson'
)
provides=("vapoursynth-plugin-${_plug}"
'libbestsource.so')
conflicts=("vapoursynth-plugin-${_plug}")
source=("${_plug}::git+https://github.com/vapoursynth/bestsource.git"
"libp2p::git+https://bitbucket.org/the-sekrit-twc/libp2p.git#commit=1e3818bd7277165819f659d410873fe5dab37af6")
sha256sums=('SKIP'
'SKIP')
options=('debug')
pkgver() {
cd "$_plug"
# echo "$(git describe --long --tags | tr - .)"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
mkdir -p build
cd "$_plug"
git submodule init
git config submodule.libp2p.url "$srcdir/libp2p"
git -c protocol.file.allow=always submodule update
}
build() {
cd build
arch-meson "../$_plug" \
--libdir /usr/lib/vapoursynth
ninja
}
package(){
DESTDIR="$pkgdir" ninja -C build install
install -Dm644 "${srcdir}/bestsource/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|