PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Maintainer:  Gustavo Alvarez <sl1pkn07@gmail.com>

_plug=bm3dcuda
pkgname=vapoursynth-plugin-${_plug}-git
pkgver=R2.4.15.g9f7b3c1
pkgrel=1
pkgdesc="Plugin for Vapoursynth: ${_plug} (GIT version)"
arch=('x86_64')
url='https://github.com/WolframRhodium/VapourSynth-BM3DCUDA'
license=('GPL')
depends=('vapoursynth'
         'cuda'
         )
makedepends=('git'
             'cmake'
             )
provides=("vapoursynth-plugin-${_plug}")
conflicts=("vapoursynth-plugin-${_plug}")
source=("${_plug}::git+https://github.com/WolframRhodium/VapourSynth-BM3DCUDA.git")
sha256sums=('SKIP')

pkgver() {
  cd "${_plug}"
  echo "$(git describe --long --tags | tr - .)"
}

prepare() {
  mkdir -p build
}

build() {
  cd build
  CXXFLAGS+=" $(pkg-config --cflags vapoursynth)" cmake ../bm3dcuda \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_SKIP_RPATH=ON

  make
}

package(){
  install -Dm755 build/cpu_source/libbm3dcpu.so "${pkgdir}/usr/lib/vapoursynth/libbm3dcpu.so"
  install -Dm755 build/source/libbm3dcuda.so  "${pkgdir}/usr/lib/vapoursynth/libbm3dcuda.so"
  install -Dm755 build/rtc_source/libbm3dcuda_rtc.so "${pkgdir}/usr/lib/vapoursynth/libbm3dcuda_rtc.so"

  install -Dm644 "${_plug}/README.md" "${pkgdir}/usr/share/doc/vapoursynth/plugins/${_plug}/README.md"
}