blob: 8b57284fa8c9f3d8951ed82d05466445d7dec388 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>
# Contributor: Mikuro Kagamine <mikurok@forgecrushing.com>
_plug=dfttest2
pkgname=vapoursynth-plugin-${_plug}-git
pkgver=v5.6.g082fe6a
pkgrel=1
pkgdesc="Plugin for Vapoursynth: ${_plug} (GIT Version)"
arch=('x86_64')
url='https://github.com/AmusementClub/vs-dfttest2'
license=('GPL2')
depends=('vapoursynth' 'cuda')
makedepends=('git' 'cmake' 'ninja' 'gcc')
provides=("vapoursynth-plugin-${_plug}")
conflicts=("vapoursynth-plugin-${_plug}")
source=("${_plug}::git+https://github.com/AmusementClub/vs-dfttest2")
sha256sums=('SKIP')
options=('debug')
_site_packages="$(python -c 'import sysconfig; print(sysconfig.get_paths()["purelib"])')"
pkgver() {
cd "${_plug}"
echo "$(git describe --long --tags | tr - . | tr -d r)"
}
prepare() {
cd "${_plug}"
git submodule update --init --recursive
}
build() {
# This is based on what the project's CI is doing
export CC=gcc
export CXX=g++
cmake \
-B "build" \
-S "${_plug}" \
-G Ninja \
-D CMAKE_BUILD_TYPE=Release \
-D CMAKE_C_COMPILER="${CC}" \
-D CMAKE_CXX_COMPILER="${CXX}" \
-D CMAKE_CXX_FLAGS_RELEASE="-ffast-math -march=native" \
-D CMAKE_INSTALL_PREFIX=/usr \
-D ENABLE_CUDA=1 \
-D USE_NVRTC_STATIC=ON \
-D ENABLE_CPU=1 \
-W no-dev
cmake --build "build" --config Release
}
package() {
DESTDIR="$pkgdir" cmake --install build
install -Dm644 "${_plug}/${_plug}.py" "${pkgdir}${_site_packages}/${_plug}.py"
python -m compileall -q -f -d "${_site_packages}" "${pkgdir}${_site_packages}/${_plug}.py"
python -OO -m compileall -q -f -d "${_site_packages}" "${pkgdir}${_site_packages}/${_plug}.py"
}
|