blob: 096dab37765c2b3e74c63939e595ce3a5814cc2c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>
_plug=knlmeanscl
pkgname=vapoursynth-plugin-${_plug}-git
pkgver=1.1.1.r509.c5c48f3
pkgrel=1
pkgdesc="Plugin for Vapoursynth: ${_plug} (GIT version)"
arch=('x86_64')
url='http://forum.doom9.org/showthread.php?t=171379'
license=('GPL')
depends=('ocl-icd'
'opencl-driver'
'vapoursynth'
)
makedepends=('git'
'opencl-headers'
)
conflicts=("vapoursynth-plugin-${_plug}")
provides=("vapoursynth-plugin-${_plug}")
source=("${_plug}::git+https://github.com/Khanattila/KNLMeansCL.git")
sha256sums=('SKIP')
pkgver() {
cd "${_plug}"
_ver="$(cat KNLMeansCL/NLMDefault.h | grep -m1 '#define VERSION' | grep -o "[[:digit:]]*" | paste -sd'.')"
echo "${_ver}.r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}
build() {
cd "${_plug}"
./configure \
--install=/usr/lib/vapoursynth \
--extra-cxxflags="${CXXFLAGS} ${CPPFLAGS}" \
--extra-ldflags="${LDFLAGS//--as-needed,/}"
make
}
package(){
make -C "${_plug}" DESTDIR="${pkgdir}" install
}
|