summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: a9f43c1c2bf753eab43730edc4d583d35e26dcc2 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
# Maintainer:  Gustavo Alvarez <sl1pkn07@gmail.com>

_plug=replaceframes
pkgname=vapoursynth-plugin-${_plug}-hg
pkgver=4.37bd14b3cff3
pkgrel=1
pkgdesc="Plugin for Vapoursynth: ${_plug} (HG version)"
arch=('x86_64')
url='https://bitbucket.org/James1201/vapoursynth-replaceframes'
license=('custom:WTFPL')
depends=('vapoursynth'
         'gcc-libs'
         )
makedepends=('mercurial')
provides=("vapoursynth-plugin-${_plug}")
conflicts=("vapoursynth-plugin-${_plug}")
source=("${_plug}::hg+https://bitbucket.org/James1201/vapoursynth-replaceframes")
sha256sums=('SKIP')

pkgver() {
  cd "${_plug}"
  echo "$(hg log -r -1 --template '{rev}.{node|short}\n')"
}

prepare() {
  mkdir -p build

  cd "${_plug}"
  chmod +x autogen.sh
  ./autogen.sh
}

build() {
  cd build
  ../"${_plug}"/configure \
    --libdir="/usr/lib/vapoursynth"

  make
}

package(){
  make -C build DESTDIR="${pkgdir}" install

  install -Dm644 "${_plug}/README.md" "${pkgdir}/usr/share/doc/vapoursynth/plugins/${_plug}/README.md"
  install -Dm644 "${_plug}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}