summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 7fc36afb4ed7308c39a524bc335e05824bb14948 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
# Maintainer:  Gustavo Alvarez <sl1pkn07@gmail.com>

_plug=smoothuv
pkgname=vapoursynth-plugin-${_plug}-git
pkgver=v2.0.g0ba81c9
pkgrel=2
pkgdesc="Plugin for Vapoursynth: ${_plug} (GIT version)"
arch=('x86_64')
url="https://forum.doom9.org/showthread.php?t=175520"
license=('GPL')
depends=('vapoursynth')
makedepends=('git'
             'meson'
             )
provides=("vapoursynth-plugin-${_plug}")
conflicts=("vapoursynth-plugin-${_plug}")
source=("${_plug}::git+https://github.com/dubhater/vapoursynth-${_plug}.git")
sha256sums=('SKIP')

_site_packages="$(python -c "from distutils.sysconfig import get_python_lib; print(get_python_lib())")"

pkgver() {
  cd "${_plug}"
  echo "$(git describe --long --tags | tr - .)"
}

prepare() {
  mkdir -p build
}

build() {
  cd build
    CXXFLAGS+=' -fpeel-loops' arch-meson "../${_plug}" \
    --libdir /usr/lib/vapoursynth

  ninja
}

package(){
  DESTDIR="${pkgdir}" ninja -C build install

  install -Dm644 "${_plug}/readme.rst" "${pkgdir}/usr/share/doc/vapoursynth/plugins/${_plug}/readme.rst"

  install -Dm644 "${_plug}/RainbowSmooth.py" "${pkgdir}${_site_packages}/RainbowSmooth.py"
  python -m compileall -q -f -d "${_site_packages}" "${pkgdir}${_site_packages}/RainbowSmooth.py"
  python -OO -m compileall -q -f -d "${_site_packages}" "${pkgdir}${_site_packages}/RainbowSmooth.py"
}