blob: 64afc13975945273250223411155272a87c38b14 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>
_plug=vardautomation
pkgname=vapoursynth-plugin-${_plug}-git
pkgver=1.2.4.3.gfae0549
pkgrel=1
pkgdesc="Plugin for Vapoursynth: ${_plug} (GIT version)"
arch=('any')
url='https://github.com/Ichunjo/vardautomation'
license=('MIT')
depends=(
'vapoursynth'
'python-langcodes'
# language-data
'python-loguru'
'python-lxml'
'python-numpy'
'python-psutil'
'python-pymediainfo'
'python-pyparsebluray-git'
'python-pyparsedvd-git'
'python-pytimeconv-git'
'python-requests'
'python-requests-toolbelt'
'python-rich'
'python-typing_extensions'
'vapoursynth-plugin-vardefunc-git'
)
makedepends=(
'git'
'python-build'
'python-wheel'
'python-installer'
'python-setuptools'
)
provides=("vapoursynth-plugin-${_plug}")
conflicts=("vapoursynth-plugin-${_plug}")
source=("${_plug}::git+https://github.com/Ichunjo/vardautomation.git")
sha256sums=('SKIP')
pkgver() {
cd "${_plug}"
echo "$(git describe --long --tags | tr - . | tr -d v)"
}
build() {
cd "${_plug}"
python -m build --wheel --no-isolation
}
package() {
cd "${_plug}"
python -m installer --destdir="${pkgdir}" dist/*.whl
install -Dm644 README.md "${pkgdir}/usr/share/doc/vapoursynth/tools/${_plug}/README.md"
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|