blob: cd045d3ba54f9124af034c92d2d3d3b33ef61824 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>
_plug=vmaf
pkgname=vapoursynth-plugin-${_plug}-git
pkgver=r6.0.gf1b7159
pkgrel=1
pkgdesc="Plugin for Vapoursynth: ${_plug} (GIT version)"
arch=('x86_64')
url='https://forum.doom9.org/showthread.php?t=175862'
license=('GPL')
depends=('vapoursynth'
'vmaf'
)
makedepends=('git'
'meson'
)
provides=("vapoursynth-plugin-${_plug}")
conflicts=("vapoursynth-plugin-${_plug}")
source=("${_plug}::git+https://github.com/HomeOfVapourSynthEvolution/VapourSynth-VMAF.git")
sha256sums=('SKIP')
pkgver() {
cd "${_plug}"
echo "$(git describe --long --tags | tr - .)"
}
prepare() {
mkdir -p build
# rename models path
sed "s|model/|${_plug}-models/|g" -i "${_plug}/VMAF/VMAF.cpp"
}
build() {
cd build
arch-meson "../${_plug}" \
--libdir /usr/lib/vapoursynth
ninja
}
package(){
DESTDIR="${pkgdir}" ninja -C build install
mv "${pkgdir}/usr/lib/vapoursynth/model" "${pkgdir}/usr/lib/vapoursynth/${_plug}-models"
chmod -R a+w "${pkgdir}/usr/lib/vapoursynth/${_plug}-models"
install -Dm644 "${_plug}/README.md" "${pkgdir}/usr/share/doc/vapoursynth/plugins/${_plug}/README.md"
}
|