PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Josh Holmer <jholmer.in@gmail.com>

_plug=vsmuxtools
pkgname=vapoursynth-plugin-${_plug}-git
pkgver=0.4.2.2.g44bf19b
pkgrel=1
pkgdesc="Plugin for Vapoursynth: ${_plug} (GIT version)"
arch=('any')
url='https://github.com/Jaded-Encoding-Thaumaturgy/vs-muxtools'
license=('MIT')
depends=(
	'vapoursynth'
	'vapoursynth-plugin-vstools'
	'python-numpy'
	'python-muxtools'
)
makedepends=(
	'git'
	'python-build'
	'python-wheel'
	'python-installer'
	'python-setuptools'
	'python-hatchling'
	'python-versioningit'
)
provides=("vapoursynth-plugin-${_plug}")
conflicts=("vapoursynth-plugin-${_plug}")
source=("${_plug}::git+https://github.com/Jaded-Encoding-Thaumaturgy/vs-muxtools.git")
sha256sums=('SKIP')

pkgver() {
	cd "${_plug}"
	echo "$(git describe --long --tags | tr - . | tr -d v)"
}

build() {
	cd "${_plug}"
	python -m build --wheel --no-isolation
}

package() {
	cd "${_plug}"
	python -m installer --destdir="${pkgdir}" dist/*.whl

	install -Dm644 README.md "${pkgdir}/usr/share/doc/vapoursynth/tools/${_plug}/README.md"
	install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}