blob: 549122d9bc4ffb3f6d418eb831dd0f957cdcf469 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Zoltan Tombol <zoltan (dot) tombol (plus) aur (at) gmail (dot) com>
pkgname=varrick-git
pkgver=0.2.0.r10.g9934958
pkgrel=1
pkgdesc="A convenient template engine to just 'Do the thing!'"
arch=(any)
url="https://github.com/ztombol/varrick"
license=('GPL3')
depends=('bash' 'sed')
makedepends=('git' 'ruby-ronn')
checkdepends=('bats-git')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("${pkgname%-git}::git+https://github.com/ztombol/${pkgname%-git}")
sha512sums=('SKIP')
pkgver() {
cd "${srcdir}/${pkgname%-git}"
printf "%s" "$(git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g')"
}
build() {
cd "${srcdir}/${pkgname%-git}"
make build
}
check() {
cd "${srcdir}/${pkgname%-git}"
make -k check
}
package() {
cd "${srcdir}/${pkgname%-git}"
make DESTDIR="$pkgdir" \
prefix='/usr' \
libexecdir='/usr/lib' \
install
}
# vim:set ts=2 sw=2 et:
|