blob: 2fd68ff17794e4847c83118248ace4e36528ff2c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
pkgname='vault-git'
pkgdesc='A tool for managing secrets'
pkgver=v0.2.0.r48.g23d4906
pkgrel=1
url='https://vaultproject.io/'
license=('MPL')
arch=('i686' 'x86_64')
makedepends=('godep')
depends=('glibc')
provides=("${pkgname%-git}")
conflicts=("${provides[@]}")
install='vault.install'
source=("${pkgname}::git+https://github.com/hashicorp/vault/"
'vault.service'
'vault.hcl')
sha512sums=('SKIP'
'a97d10208fd99b29cf532c9b5882fe1bbb3faee1d1d706f95a9c379fef461c65a9f16c8530438920024e69871ebd8c7329e6b65025ad65092950bfb74ce393b3'
'8c064aa5dcca84822c1fa85e9d0ff520df46f794b2e9c689a9b4f81f74279387b3aebc08b3ca26cf786c2fcf1a330e765bf5a511074c24f87e5346672346ba1c')
pkgver () {
cd "${pkgname}"
( set -o pipefail
git describe --long --tags 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
)
}
prepare () {
mkdir -p "${pkgname}/,build"
}
build () {
cd "${pkgname}"
godep go build -x -v -o ,build/vault
}
package () {
cd "${pkgname}"
install -Dm755 ,build/vault "${pkgdir}/usr/bin/vault"
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm644 "${srcdir}/vault.hcl" "${pkgdir}/etc/vault.hcl"
install -Dm644 "${srcdir}/vault.service" \
"${pkgdir}/usr/lib/systemd/system/vault.service"
for file in README.md CHANGELOG.md ; do
install -Dm644 "${file}" "${pkgdir}/usr/share/doc/${pkgname}/${file}"
done
}
|